How to deploy Library contract separate from the main contract and link it

Question

For deployment I am using remix. When I deploy Hello.sol the compiler typically merges SafeMath.sol as a part of the main contract (Hello.sol) and deploys. This adds up library and main contract's deployment cost as whole. I want to do this operation separately in order to divide deployment cost in to multiple operations.

[Q] Is there any way to first deploy the library contract separately from the main contract and than link it to the main contract on remix? Should I use Truffle or follow different approach for this?

I have following simple contract, remix deploys Hello.sol as as single contract which also includes SafeMath.sol:

SafeMath.sol

pragma solidity ^0.5.0;

library SafeMath {
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "addition overflow");

        return c;
    }
}

---

Hello.sol

pragma solidity ^0.5.0;

import "./SafeMath.sol";

contract Hello {
    using SafeMath for uint256;
    uint value;

    constructor() public
    {
        value = value.add(100);
    }    
}

Answer 1

It seems that Remix does this automatically.

Library code:

pragma solidity ^0.5.10;

library Foo {
    struct F {
        uint256 x;
    }

    function foo (F storage f) external {
        f.x = 123456789;
    }
}

Main contract code:

pragma solidity ^0.5.10;

import './Foo.sol';

contract Bar {
    Foo.F public f;

    function bar () public {
        Foo.foo (f);
    }
}

When I tell Remix to deploy Bar contract, it actually executes two separate transactions: the first to deploy Foo library and the second to deploy Bar contract linked to the Foo library:

Though this way you cannot link library that is already deployed.

Answer 2

in truffle you can do something like this:

const ConvertLib = artifacts.require("ConvertLib");
const MetaCoin = artifacts.require("MetaCoin");

module.exports = function(deployer) {
  deployer.deploy(ConvertLib);
  deployer.link(ConvertLib, MetaCoin);
  deployer.deploy(MetaCoin);
};

from

https://github.com/truffle-box/metacoin-box/blob/master/migrations/2_deploy_contracts.js

I'm not aware if that is possible with remix :/

Answer 3

I deployed the library as contract (and also change the function to public) and linked the “contract-library” like this SafeMath safeMath = SafeMath(0xF2fD4E3A5b94f0B4D8EE74C009E12F698906420b);.

Here is the code of the contract Hello:

pragma solidity ^0.5.10;

contract SafeMath {
    function add(uint256 a, uint256 b) public pure returns (uint256);
}

contract Hello {
    SafeMath safeMath = SafeMath(0xF2fD4E3A5b94f0B4D8EE74C009E12F698906420b);

    uint public value;

    constructor() public
    {
        value = safeMath.add(value, 100);
    }    
}

(Technically I think it’s a solution for your issue but it’s not very elegant.)

See https://kovan.etherscan.io/address/0x031c90e551c760c895cdf7d14e940e83578f9cc0#code for the contract. And see https://kovan.etherscan.io/address/0xF2fD4E3A5b94f0B4D8EE74C009E12F698906420b#code for the “contract-library”.

Answer 4

I had this similar issue before, and finally got it work like this

const ConvertLib = artifacts.require("ConvertLib");
const MetaCoin = artifacts.require("MetaCoin");

module.exports = function(deployer) {
  ConvertLib.address = "0xabce987676...";
  deployer.link(ConvertLib, MetaCoin);
  deployer.deploy(MetaCoin);
};