Can anyone explain how bytes memory can be converted to address type in solidity

Question

when I am using below function to convert bytes memory to address, this is working fine.

Suppose input to the function is 0X0000000000000000000000004af3246b4fff356261136f113411cb187134D675

I am getting the output 0x4af3246b4fff356261136f113411cb187134D675

    function bytesToAddress(bytes memory bys) public pure returns (address addr) {

        assembly {
             addr := mload(add(add(bys, 32), 0))
       }
    }

Can, anyone explain me, what actually happening ?

Answer 1

The expression add(bys, 32):

Returns a pointer to the actual data, which starts after the first 32 bytes in the bys array (those first 32 bytes contain the length of the bys array).

---

The expression mload(x):

Loads the data pointed to by x, so you can just as well use mload(add(bys, 32)), because there is no added value in doing x + 0.

---

The expression addr := y:

Stores the value of y into the variable addr (in your case, since the value of y is 32-byte long and the type of addr is 20-byte long, only the 20 least significant bytes are stored).

Answer 2

You may meet the following code in many projects:

contract A {

    event Log(address addr);

    function() external {
        emit Log(bytesToAddress(msg.data));
    }

    function bytesToAddress(bytes memory source) public pure returns(address addr) {
        assembly {
            addr := mload(add(source, 0x14))
        }
    }
}

Actually source when meet in assembly refers to 52 bytes:

0000000000000000000000000000000000000000000000000000000000000020
4af3246b4fff356261136f113411cb187134D675

So shifting 0x14 bytes (20 bytes) means capturing this value:

                                        V
0000000000000000000000000000000000000000000000000000000000000020
4af3246b4fff356261136f113411cb187134D675
                                       ^

This:

0000000000000000000000204af3246b4fff356261136f113411cb187134D675

But since return type is address Solidity compiler inserts code to erase top-12 bytes of address:

addr = addr & ((1 << 160) - 1)

Which leads to:

0000000000000000000000204af3246b4fff356261136f113411cb187134D675
&
000000000000000000000000ffffffffffffffffffffffffffffffffffffffff
=
0000000000000000000000004af3246b4fff356261136f113411cb187134D675
                      ^