structs, mappings, & enums. How to make them work together?

Question

I have this code. My question pretains to struct variables weapons, armour, & stats

enum Armour {Chest, Helm, Boots, Leggings, Gloves, Shield} 
enum Weapon {Sword, Axe, Wand, Gun, Hammer, Fist}

struct Statistics { uint16 testing; }

struct Character {string name;
                  uint dna;
                  mapping (uint => Statistics) stats; 
                  mapping (uint => Weapon[10]) weapons; 
                  Armour[10] armour;                  
    }

Character[] public characters;
Armour[10] armourTest;
Weapon[10] weaponsTest;

I do not see much in http://solidity.readthedocs.io/en/v0.4.21/types.html#enums about enum arrays and mappings of enums as array values.

How can I use struct variables weapons, armour, & stats after I have pushed a character to the public variable characters?

Answer 1

This is a really abbreviated snippet to give you some ideas. You may be after a more feature-complete relational model like is described here: https://medium.com/@robhitchens/enforcing-referential-integrity-in-ethereum-smart-contracts-a9ab1427ff42

pragma solidity ^0.4.19;

contract RPG {
    enum Armor {Chest, Helm, Boots, Leggings, Gloves, Shield} 
    enum Weapon {Sword, Axe, Wand, Gun, Hammer, Fist}

    struct CharacterStruct {string name;
                      bool isCharacter;
                      uint dna;
                      Armor[] armors; 
                      Weapon[] weapons;                  
        }

    mapping(address => CharacterStruct) public characterStructs;
    address[] public characters;

    modifier onlyIfRegistered() {
        require(characterStructs[msg.sender].isCharacter);
        _;
    }

    function register() public returns(bool success) {
        require(!characterStructs[msg.sender].isCharacter);
        characters.push(msg.sender);
        characterStructs[msg.sender].isCharacter = true;
        return true;
    }

    function addArmor(Armor a) public onlyIfRegistered returns(bool success) {
        characterStructs[msg.sender].armors.push(a);
        return true;
    }

    function getArmor(address player, uint row) public view returns(Armor armor) {
        return characterStructs[player].armors[row];
    }

}

Hope it helps.