Ownership isn't allocated in the contract?

Question

I've taken the below contract as an example from a tutorial and changed items highlighted in bold, as per IDE errors.

What the contract should do is allocate ownership of the item to the account that deploys the contract, then when 2 ether is paid, change the ownership to the account that made the payment. When I deploy the contract, the ownership isnt allocated to the account, instead it has the address 0x000..., and when i use the buy function, ownership does not transfer and ether is not deducted from the buyers account. Any help would be appreciated.

---

pragma solidity ^0.4.0;

contract SalesContract {

    address **public** owner;
    bool public isSold = false;
    string public salesDescription = "Honda Civic";
    uint public price = 2 ether;

    function SaleContract() {
        owner = msg.sender;
    }

    function Buy() **public** payable {
        if(msg.value >= price) {
            **owner.transfer(address(this).balance)**;
            owner = msg.sender;
            isSold = true;
        } else {
            revert();
        }
    }

}

---

Original code from tutorial:

pragma solidity ^0.4.0;

contract SalesContract {
    address public owner;
    bool public sold = false;
    string public salesDescription = 'Volvo V40 HF 56 32';
    uint price = 2 ether;

    function SalesContract() payable {
        owner = msg.sender;
    }

    function buy() payable {
        if(msg.value >= price) {
            owner.transfer(this.balance);
            owner = msg.sender;
            sold = true;
        } else {
            revert();
        }
    }
}

Answer 1

Here's the code, upgraded to solidity 5 and confirmed on Remix. Let us know if you have questions.

pragma solidity ^0.5.0;

contract SalesContract {

    address payable public owner;
    bool public isSold = false;
    string public salesDescription = "Honda Civic";
    uint public price = 2 ether;

    constructor() public {
        owner = msg.sender;
    }

    function Buy() public payable {
        if(msg.value >= price) {
            owner.transfer(address(this).balance);
            owner = msg.sender;
            isSold = true;
        } else {
            revert();
        }
    }

}

The differences:

• pragma version (line 1)
• address payable (line 5)
• constructor (line 10)

Answer 2

Maybe you should check your spelling,I think it should be "SalesContract" rather than "SaleContract",when we use the same name of the contract,we can initialize our contract right.

Answer 3

An interesting story on:

contract SalesContract {
    ...
    function SaleContract() {
        ...
    }
    ...
}

A while back, some company deployed a contract with the same typo.

Shortly thereafter, all the money deposited into that contract was stolen.

Why?

The author decided to rename the contract, but forgot to rename the constructor.

So instead of a constructor, there was now a public function available for anyone to invoke.

Switch to Solidity 0.4.21 or later, and declare constructor instead.

It will not solve this specific problem of course, because you may still make the mistake of declaring that public function, but most likely, you will start using the constructor keyword and will not step into this pitfall in the future.